// always start with this  
Names Default To Here(1);

if (NameSpaceExists("recall.example-jsl.david.burnham"),
	nsRecall = NameSpace("recall.example-jsl.david.burnham")
,
	nsRecall = NewNameSpace("recall.example-jsl.david.burnham");
	nsRecall:lstX = {};
	nsRecall:lstY = {};
);

app = NewNamespace("app.example-jsl.david.burnham");

// user-defined functions

MyGraph = Function({yCol,xCol,lstX},{default local},
	
	vlb = VListBox(
		gb = Graph Builder(
			Size( 415, 277 ),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Variables( X( Eval(xCol) ), Y( Eval(yCol) ) ),
			Elements( Points( X, Y, Legend( 2 ) ), Smoother( X, Y, Legend( 3 ) ) )
		)
	);
	
	cs = gb << Column Switcher( xCol, lstX );
	cs << Make Column Switch Handler( preCSHandler, postCSHandler );
	
	return(vlb);
	
);

MyHistograms = Function({yCol,xCol,xType},{default local},
	
	if (xType=="Continuous",
		Distribution(
			Continuous Distribution( Column( Eval(yCol) ), Summary Statistics( 1 ) ),
			Continuous Distribution( Column( Eval(xCol) ), Summary Statistics( 1 ) ),
			Histograms Only
		)
	, // else
		Distribution(
			Continuous Distribution( Column( Eval(yCol) ), Summary Statistics( 1 ) ),
			Nominal Distribution( Column( Eval(xCol) ), Frequencies( 1 ) ),
			Histograms Only
		)
	);	
	
);

MyRegression = Function({yCol,xCol},{default local},
	
	Bivariate(
		Y( Eval(yCol) ),
		X( Eval(xCol) ),
		Fit Line( {Confid Shaded Fit( 1 ), Line Color( {212, 73, 88} )} ),
		SendToReport(
			Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 310, 177 )} ),
			Dispatch( {"Linear Fit"}, "Analysis of Variance", OutlineBox, {Close( 1 )} )
		)
	);	
	
);

MyOneway = Function({yCol,xCol},{default local},
	
	Oneway(
		Y( Eval(yCol) ),
		X( Eval(xCol) ),
		Means( 1 ),
		Mean Diamonds( 1 ),
		SendToReport(
			Dispatch( {}, "Oneway Plot", FrameBox, {Frame Size( 334, 184 )} ),
			Dispatch( {"Oneway Anova"}, "Summary of Fit", OutlineBox, {Close( 1 )} ),
			Dispatch( {"Oneway Anova"}, "Pooled t Test", OutlineBox, {Close( 1 )} )
		)
	)	
	
);

preCSHandler = Empty();

postCSHandler = Function({oldCol, newCol, this},{default local},
	
	app = Namespace("app.example-jsl.david.burnham");
	app:xColName = newCol << getName;
	
	app:xType = newCol << getModelingType;
	if (app:xtype=="Continuous",
		app:btn2 << setButtonName("fit regression line");
		app:btn2 << setScript(
			app = Namespace("app.example-jsl.david.burnham");
			MyRegression(app:yColName,app:xColName)
		);
	,
		app:btn2 << setButtonName("perform oneway ANOVA");
		app:btn2 << setScript(
			app = Namespace("app.example-jsl.david.burnham");
			MyOneway(app:yColName,app:xColName)
		);
	);
	
);

// main code follows


dt = CurrentDataTable();
if (IsEmpty(dt),
	NewWindow("Missing Data", <<Modal,
		BorderBox(top(20),bottom(20),left(20),right(20),
			TextBox("No data tables are open")
		)
	);
	throw()
);

nw = NewWindow("Column Selection", <<modal,
	<<onClose(
	   lstX = clbX << getItems;
	   lstY = clbY << getItems;
	),
	BorderBox(top(10),bottom(10),left(10),right(10),
		VListBox(
			TextBox("Select response variable and predictor variables"),
			HListBox(
				PanelBox("Select Columns",
					fcs = FilterColSelector()
				),
				SpacerBox(size(10,0)),
				PanelBox("Cast Selected Columns into Roles",
					HListBox(align(center),
						ButtonBox("  Y,Response   ",
							sel = fcs << getSelected;
							clbY << append(sel);
						),
						SpacerBox(size(6,0)),
						clbY = ColListBox(numeric,maxitems(1),minitems(1),nlines(1))
					),
					SpacerBox(size(0,10)),
					HListBox(
						VListBox(
							ButtonBox("  X,Predictors  ",
								sel = fcs << getSelected;
								clbX << append(sel);							
							),
							SpacerBox(Size(0,20)),
							ButtonBox("      Recall       ",
								nsRecall = NameSpace("recall.example-jsl.david.burnham");
								clbY << setItems(nsRecall:lstY);
								clbX << setItems(nsRecall:lstX);
							)
						),
						SpacerBox(size(6,0)),
						clbX = ColListBox(minitems(1),nlines(8))
					)					
				)
			)
		)
	)
);
if (nw["Button"]==-1,throw());
if (Nitems(lstX)==0,throw());
if (Nitems(lstY)==0,throw());

nsRecall:lstX = lstX;
nsRecall:lstY = lstY;

yColName = lstY[1];
xColName = lstX[1];

NewWindow("My Report",
	BorderBox(top(0),left(10),right(10),bottom(20),
		VListBox(
			MyGraph(yColName,xColName,lstX),
			SpacerBox(size(0,20)),
			HCenterBox(
				HListBox(
					SpacerBox(size(200,0)),
					VListBox(
						btn1 = ButtonBox("view histograms"),
						btn2 = ButtonBox("")
					)
				)
			)
		)
	)
);

xtype = Column(dt,xColName) << getModelingType;

btn1 << underlineStyle(1);
btn1 << setScript(
	app = Namespace("app.example-jsl.david.burnham");
	MyHistograms(app:yColName,app:xColName,app:xType)
);

btn2 << underlineStyle(1);

if (xtype=="Continuous",
	btn2 << setButtonName("fit regression line");
	btn2 << setScript(
		app = Namespace("app.example-jsl.david.burnham");
		MyRegression(app:yColName,app:xColName)
	);
,
	btn2 << setButtonName("perform oneway ANOVA");
	btn2 << setScript(
		app = Namespace("app.example-jsl.david.burnham");
		MyOneway(app:yColName,app:xColName)
	);
);



app:yColName = yColName;
app:xColName = xColName;
app:xType = xType;
app:btn2 = btn2;